{
  inputs = {
    nixpkgs.url = "nixpkgs/nixos-unstable";
    dream2nix.url = "github:nix-community/dream2nix";
    dream2nix.inputs.nixpkgs.follows = "nixpkgs";
  };

  outputs = {
    self,
    dream2nix,
    nixpkgs,
  }: let
    eachSystem = nixpkgs.lib.genAttrs [
      "aarch64-darwin"
      "aarch64-linux"
      "x86_64-darwin"
      "x86_64-linux"
    ];
  in {
    nixosModules = rec {
      hcpy = import ./module.nix self;
      default = hcpy;
    };

    packages = eachSystem (system: let
      pkgs = nixpkgs.legacyPackages.${system};
    in rec {
      hcpy-raw = dream2nix.lib.evalModules {
        packageSets.nixpkgs = pkgs;
        modules = [
          ./package.nix
          {
            paths.projectRootFile = "flake.nix";
            paths.lockFile = "lock.${system}.json";
            paths.projectRoot = ./.;
            paths.package = ./.;
          }
        ];
      };

      hcpy = pkgs.callPackage ./wrapper.nix {inherit hcpy-raw;};

      default = hcpy;
    });
  };
}